Maybe you can try with a helper table and a VBA function:

1. Create a new table with sequence numbers 0,1,2,3 as rows (integer column ‘Seq’
   ): tblSeq, with max being maximum no of parts you expect,
2. Create a VBA function to extract the subpart of the string, given its position:

Public Function GetSubString(Str As String, Seq As Integer) As String
   Dim strRetVal As String, CommaPos As Integer, i As Integer, CommaPosNext As Integer
   strRetVal = ""
   CommaPos = 0
   For i = 1 To Seq
       CommaPos = InStr(CommaPos + 1, Str, ",")
   Next i
   CommaPosNext = InStr(CommaPos + 1, Str, ",")
   GetSubString = Mid(Str, CommaPos + 1, IIf(CommaPosNext = 0, 255, CommaPosNext - CommaPos - 1))
   
End Function

then your query might be like:

SELECT TBL.ID, TBL.Document, TBL.Revision, Seq.Seq, GetSubString(TBL.Revision,Seq.Seq) as Rev
from YourTbl as TBL
     inner join
     tblSeq Seq
on len(TBL.Revision)-len(replace(TBL.Revision,',',''))>=Seq.Seq

Not claiming that it would perform better than any other option, or error free.

You can use VBA and recordset to populate a new table:

Option Explicit

Private rsIN As Recordset
Private rsOUT As Recordset

Sub Fill_New()
    Dim dbs As Database
    Set dbs = CurrentDb
    Set rsIN = dbs.OpenRecordset("8110", dbOpenForwardOnly, dbReadOnly)
    Set rsOUT = dbs.OpenRecordset("NEW8110", , dbAppendOnly)
    
    Dim i As Integer
    Do Until rsIN.EOF
        Dim documents As Variant
        documents = Split(rsIN("Document"), ",")
        If UBound(documents) = 0 Then ' single value in document field '
            AddNew ID:=rsIN("ID"), Document:=rsIN("Document"), revision:=rsIN("Revision")
        Else ' comma seperated values in document field '
            Dim revisions As Variant
            revisions = Split(rsIN("Revision"), ",")
            If InStr(rsIN("Document"), "/") > 0 Then ' / used for revisions '
                AddNew ID:=rsIN("ID"), Document:=Trim(documents(0)), revision:=Trim(revisions(0))
                Dim last_slash_pos As Integer
                last_slash_pos = InStrRev(documents(0), "/")
                Dim base_text As String
                base_text = Left(documents(0), last_slash_pos - 1)
                For i = LBound(documents) + 1 To UBound(documents)
                    AddNew ID:=rsIN("ID"), Document:=base_text & Trim(documents(i)), revision:=Trim(revisions(i))
                Next
            Else ' comma seperated '
                For i = LBound(documents) To UBound(documents)
                    AddNew ID:=rsIN("ID"), Document:=Trim(documents(i)), revision:=Trim(revisions(i))
                Next
            End If
        End If
        rsIN.MoveNext
    Loop
    rsOUT.Close
    Set rsOUT = Nothing
    rsIN.Close
    Set rsIN = Nothing
    Set dbs = Nothing
End Sub

Private Sub AddNew(ID As String, Document As String, revision As String)
    rsOUT.AddNew
    rsOUT("ID") = ID
    rsOUT("Document") = Document
    rsOUT("Revision") = revision
    rsOUT.Update
End Sub