Try this:

let
    Source = Excel.CurrentWorkbook(){[Name="Table1"]}[Content],
    #"Changed Type" = Table.TransformColumnTypes(Source,{{"Date", type date}, {"Time", type number}, {"Letter", type text}, {"Data", type number}}),
    #"Added Index" = Table.AddIndexColumn(#"Changed Type", "Index", 0, 1,  Int64.Type),
    Page = Table.TransformColumns( #"Added Index", {{"Index", each if Number.Mod(_,2) = 0 then _ else _-1}}),
    #"Grouped Rows" = Table.Group(Page, {"Index"}, {{"All", each _, type table [Date=nullable date, Time=nullable number, Letter=nullable text, Data=nullable number, Index=number]}}),
    Logic = Table.TransformColumns( #"Grouped Rows",{{"All", (x)=> let
        rec1 = x{0},
        rec2 = x{1},
        same = if rec1[Letter] = rec2[Letter] then true else false,
        logic1 = if same and rec1[Time] < rec2[Time] then  {Record.Combine({rec1, [Letter="A", Index=rec1[Index]+1]}),Record.Combine({rec2, [Letter="B", Index=rec2[Index]+2]})} else 
        if same and rec1[Time] > rec2[Time] then {Record.Combine({rec1, [Letter="B",Index=rec1[Index]+1]}),Record.Combine({rec2, [Letter="A", Index=rec2[Index]+2]})} else 
        if not same and rec1[Letter] = "A" then {Record.Combine({rec1, [Index=rec1[Index]+1]}),Record.Combine({rec2, [ Index=rec2[Index]+2]})} else 
        if not same and rec1[Letter] = "B" then {Record.Combine({rec1, [Index=rec1[Index]+2]}),Record.Combine({rec2, [ Index=rec2[Index]+1]})} else null
        in Table.FromRecords( logic1)
        }}),
    #"Removed Columns" = Table.RemoveColumns(Logic,{"Index"}),
    #"Expanded All" = Table.ExpandTableColumn(#"Removed Columns", "All", {"Date", "Time", "Letter", "Data", "Index"}, {"Date", "Time", "Letter", "Data", "Index"}),
    #"Changed Type1" = Table.TransformColumnTypes(#"Expanded All",{{"Date", type date}, {"Time", type number}, {"Letter", type text}, {"Data", type number}, {"Index", Int64.Type}}),
    #"Sorted Rows" = Table.Sort(#"Changed Type1",{{"Index", Order.Ascending}})
in
    #"Sorted Rows"

This code seems to work with your data. Could be modified depending on your actual setup.

• Assumes each month’s table is read in as a separate query, and the data types are properly set.

• Add a blank query

• Paste the code below into the Advanced Editor

• *Rename that query according to the Code Comments

//Rename: fnFixLetter

(tbl as table)=>

let 

//Sort by date and time, ascending
   #"Sorted Rows" = Table.Sort(tbl,{{"Date", Order.Ascending}, {"Time", Order.Ascending}}),

//ASSUMPTION: there are NO missing entries, so grouping by pairs after sorting by date and time will always return the relevant rows
    #"Added Index" = Table.AddIndexColumn(#"Sorted Rows", "Index", 0, 1, Int64.Type),
    #"Inserted Integer-Division" = Table.AddColumn(#"Added Index", "Integer-Division", each Number.IntegerDivide([Index], 2), Int64.Type),

//Remove unneeded Index Column
    #"Removed Columns" = Table.RemoveColumns(#"Inserted Integer-Division",{"Index"}),

//Group by Integer-Divide (the pairs)
    #"Grouped Rows" = Table.Group(#"Removed Columns", {"Integer-Division"}, {
        
    //Do the magic
        {"all", (t)=> let 
            ltrs = t[Letter],

            //if the letters are identical then they should {"A","B"}
            order = if List.Count(List.Distinct(ltrs)) = 1 then {"A","B"} else ltrs,

            //Replace the Letters column with either {"A","B"} or leave what was there
            tbl= Table.FromColumns(
                    Table.ToColumns(
                        Table.RemoveColumns(t,{"Letter","Integer-Division"}))
                     & {order},{"Date","Time","Data","Letter"}),

            //resort each pair by Letter
            reSort = Table.Sort(tbl,{"Letter", Order.Ascending})
                    
            in reSort,
            type table[Date=nullable date, Time=nullable time,Data=nullable number, Letter=nullable text] 

        }}),

//Cleanup
    #"Removed Columns1" = Table.RemoveColumns(#"Grouped Rows",{"Integer-Division"}),
    #"Expanded all" = Table.ExpandTableColumn(#"Removed Columns1", "all", {"Date", "Time", "Data", "Letter"}),
    #"Reorder Columns" = Table.ReorderColumns(#"Expanded all", {"Date","Time","Letter","Data"})
in 
        #"Reorder Columns"

Now, in a new query, combine all of the existing tables

let 

//List of all the tables to be combined, in order
    tbls = {April, May},

    append = List.Accumulate(
        tbls,
        #table({},{}),
        (s,c)=> Table.Combine({s,fnFixLetter(c)})
    )
in 
    append

Data Tables

Results