For the first table: =SUM(IF((LEFT($B$1:$H$1,1)=LEFT(B$15,1))*($A16=$A$2:$A$3),$B$2:$H$3,""))

This formula can be dragged right and down as needed.

Refer to the image below to see what each arguments contains/refers to.

For Table 2: =SUM(IF((LEFT($B$1:$H$1,1)=LEFT(B19,1))*((CHOOSEROWS(TEXTSPLIT($A20,," & "),1)*1=$A$2:$A$3)+(CHOOSEROWS(TEXTSPLIT($A20,," & "),2)*1=$A$2:$A$3)),$B$2:$H$3,""))

Here you have to make sure that your COA is always formatted the same: ### & ###.

I suspect there might be an easier/better way to do Table 2, but it works.

Using SUMPRODUCT and MAKEARRAY:

First

=LET(
    tbCOA, A1:H3,
    coa, DROP(INDEX(tbCOA, , 1), 1),
    amts, DROP(tbCOA, 1, 1),
    amt_header, DROP(INDEX(tbCOA, 1, ), , 1),
    amt_group, --SUBSTITUTE(B7:D7, "+", ""),
    sum_amt, LAMBDA(coa_row, amt_grp_col,
        SUMPRODUCT(
            amts * (INDEX(coa, coa_row, 1) = coa) *
                IFERROR(
                    N(XMATCH(amt_header, amt_group, -1) = amt_grp_col),
                    0
                )
        )
    ),
    MAKEARRAY(ROWS(coa), COLUMNS(amt_group), sum_amt)
)

Second

=LET(
    tbCOA, A1:H3,
    coa, DROP(INDEX(tbCOA, , 1), 1),
    coas, A14,
    amts, DROP(tbCOA, 1, 1),
    amt_header, DROP(INDEX(tbCOA, 1, ), , 1),
    amt_group, --SUBSTITUTE(B7:D7, "+", ""),
    sum_amt, LAMBDA(coa_row, amt_grp_col,
        SUMPRODUCT(
            amts *
                ISNUMBER(XMATCH(coa, TRIM(TEXTSPLIT(INDEX(coas, coa_row, 1), "&")))) *
                IFERROR(N(XMATCH(amt_header, amt_group, -1) = amt_grp_col), 0)
        )
    ),
    MAKEARRAY(ROWS(coas), COLUMNS(amt_group), sum_amt)
)