I’ve written a stylesheet based on your code, and added an auxiliary function uml:parse-xml-robustly, which returns a map as you specified, and I changed your existing function so that it uses this new function in place of parse-xml(), and extracts the parsed XML (if any) from the map which it returns.

It wasn’t entirely clear what you wanted to do about errors. You said you wanted your robust parser to return a map whose error key would be associated with the error value. So I chose to return an error in the form of another map, with keys code, description, and value, all with string values.

If the map returned by uml:parse-xml-robustly() doesn’t contain the parsed XML, then I use another auxiliary function to return the error map from that map in the form of an element (because the function is declared to return an element).

As a test I added a template to match an element called element and invoke the function.

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:uml="https://example.com/uml"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:err="http://www.w3.org/2005/xqt-errors"
  xmlns:map="http://www.w3.org/2005/xpath-functions/map"
  exclude-result-prefixes="#all">
  
  <xsl:output method="xml" indent="yes"/>
  <xsl:mode on-no-match="shallow-copy"/>
  
  <xsl:template match="element">
    <xsl:variable name="parser" select="uml:documentation-parser(())"/>
    <xsl:copy>
      <xsl:sequence select="$parser(.)"/>
    </xsl:copy>
  </xsl:template>
  
  <xsl:function name="uml:parse-xml-robustly" as="map(*)">
    <xsl:param name="text" as="xs:string"/>
    <xsl:try>
      <xsl:sequence select="
        map{
          'text': $text,
          'xml': parse-xml($text),
          'error': ()
        }
      "/>
      <xsl:catch select="
        map{
          'text': $text,
          'xml': (),
          'error': map{
            'code': 'Q{' || namespace-uri-from-QName($err:code) || '}' || local-name-from-QName($err:code),
            'description': $err:description,
            'value': $err:value
          }
        }
      "/>
    </xsl:try>
  </xsl:function>
  
  <xsl:function name="uml:error-as-element" as="element(error)">
    <xsl:param name="error" as="map(*)"/>
    <error>
      <xsl:for-each select="map:keys($error)">
        <xsl:attribute name="{.}" select="$error(.)"/>
      </xsl:for-each>
    </error>
  </xsl:function>
  
  <xsl:function name="uml:documentation-parser" as="function (element()) as element()*">
    <xsl:param name="entity-file" as="xs:string?"/>
    <xsl:sequence select="
      let $doctype := if ($entity-file) then
          '<!DOCTYPE root [<!ENTITY % entities SYSTEM ''' || $entity-file || '''>%entities;]>'
      else
          '',
          $prolog := '<root xmlns=''http://docbook.org/ns/docbook''>',
          $epilog := '</root>'
      return
          function ($element as element(*)) as element()* {
              let $text := $element/ownedComment/@body
              return
                  if ($text) then
                    let $result := 
                      concat($doctype, $prolog, $text, $epilog) => uml:parse-xml-robustly()
                    return
                      ($result('xml')/*/*, $result('error')!uml:error-as-element(.))[1]
                  else
                      ()
          }"/>
    </xsl:function>
</xsl:stylesheet>

Test document:

<root>
  <element>
    <ownedComment body="<p>This is a <i>comment</i></p>"/>
  </element>
  <element>
    <ownedComment body="<p>This is a <i>comment</i><p>"/>
  </element>
</root>

Result:

<root>
   <element>
      <p xmlns="http://docbook.org/ns/docbook">This is a <i>comment</i>
      </p>
   </element>
   <element>
      <error code="Q{http://www.w3.org/2005/xqt-errors}FODC0006"
             value="org.xml.sax.SAXParseException; systemId: urn:from-string; lineNumber: 1; columnNumber: 77; The element type "p" must be terminated by the matching end-tag "</p>"."
             description="First argument to parse-xml() is not a well-formed and namespace-well-formed XML document. org.xml.sax.SAXParseException; systemId: urn:from-string; lineNumber: 1; columnNumber: 77; The element type "p" must be terminated by the matching end-tag "</p>".The element type "p" must be terminated by the matching end-tag "</p>"."/>
   </element>
</root>